Rules for integrands of the form(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)

0.  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0

x:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.3.2.4.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (1/(c^p))∫(((d+e (x^n)))^q) ((((b/2)+c (x^n)))^(2 p))dx

Program code:

(* Int[(d_+e_.*x_^n_.)^q_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  1/c^p*Int[(d+e*x^n)^q*(b/2+c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0                 Necessary?

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/(((d+e (x^n)))^(2 p)))==0

Note: If  (b^2)-4 a c==0 ∧ 2 c d-b e==0, then a+b z+c (z^2)==(c/(e^2)) (((d+e z))^2)

Rule 1.2.3.3.0.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ 2 c d-b e==0, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^p)/(((d+e (x^n)))^(2 p))) ∫(((d+e (x^n)))^(q+2 p))dx

Program code:

Int[(d_+e_.*x_^n_.)^q_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^p/(d+e*x^n)^(2*p)*Int[(d+e*x^n)^(q+2*p),x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[2*c*d-b*e,0]

2:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/((((b/2)+c (x^n)))^(2 p)))==0

Note: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.3.3.0.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((c^(IntPart[p]))((((b/2)+c (x^n)))^(2 FracPart[p]))))∫(((d+e (x^n)))^q) ((((b/2)+c (x^n)))^(2 p))dx

Program code:

Int[(d_+e_.*x_^n_.)^q_.*(a_+b_.*x_^n_.+c_.*x_^n2_.)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/(c^IntPart[p]*(b/2+c*x^n)^(2*FracPart[p]))*Int[(d+e*x^n)^q*(b/2+c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

1:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (p|q)∈ℤ ∧ n<0

Derivation: Algebraic expansion

Basis: If  (p|q)∈ℤ, then (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)==(x^(n (2 p+q)))(((e+d (x^(-n))))^q) (((c+b (x^(-n))+a (x^(-2 n))))^p)

Rule 1.2.3.3.1: If  (p|q)∈ℤ ∧ n<0, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(x^(n (2 p+q)))(((e+d (x^(-n))))^q) (((c+b (x^(-n))+a (x^(-2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(n*(2*p+q))*(e+d*x^(-n))^q*(c+b*x^(-n)+a*x^(-2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && IntegersQ[p,q] && NegQ[n]

Int[(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(n*(2*p+q))*(e+d*x^(-n))^q*(c+a*x^(-2*n))^p,x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && IntegersQ[p,q] && NegQ[n]

2:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  n∈(SuperMinus[ℤ])

Derivation: Integration by substitution

Basis: If  n∈ℤ, then F[(x^n)]==-Subst[((F[(x^(-n))])/(x^2)),x,(1/x)] (∂_x)(1/x)

Rule 1.2.3.3.2: If  n∈(SuperMinus[ℤ]), then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  -Subst[∫(((((d+e (x^(-n))))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p))/(x^2))dx,x,(1/x)]

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  -Subst[Int[(d+e*x^(-n))^q*(a+b*x^(-n)+c*x^(-2*n))^p/x^2,x],x,1/x] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[n2,2*n] && ILtQ[n,0]

Int[(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  -Subst[Int[(d+e*x^(-n))^q*(a+c*x^(-2*n))^p/x^2,x],x,1/x] /;
FreeQ[{a,c,d,e,p,q},x] && EqQ[n2,2*n] && ILtQ[n,0]

3:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If  g∈(SuperPlus[ℤ]), then F[(x^n)]==g Subst[(x^(g-1))F[(x^(g n))],x,(x^(1/g))] (∂_x)(x^(1/g))

Rule 1.2.3.3.3: If  n∈𝔽, let g=Denominator[n], then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  g Subst[∫(x^(g-1)) (((d+e (x^(g n))))^q) (((a+b (x^(g n))+c (x^(2 g n))))^p)dx,x,(x^(1/g))]

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g-1)*(d+e*x^(g*n))^q*(a+b*x^(g*n)+c*x^(2*g*n))^p,x],x,x^(1/g)]] /;
FreeQ[{a,b,c,d,e,p,q},x] && EqQ[n2,2*n] && FractionQ[n]

Int[(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g-1)*(d+e*x^(g*n))^q*(a+c*x^(2*g*n))^p,x],x,x^(1/g)]] /;
FreeQ[{a,c,d,e,p,q},x] && EqQ[n2,2*n] && FractionQ[n]

4.  ∫(((d+e (x^n)))^q)(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ

1.  ∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ

1:  ∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ ∧ n (2 p+1)+1==0

Derivation: Trinomial recurrence 2a with a=0, m=0 and n (2 p+1)+1==0 composed with trinomial recurrene 5 with a=0

Rule 1.2.3.3.4.1.1: If  p∉ℤ ∧ n (2 p+1)+1==0, then

∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  ⟶  -(((c d-b e)(((b (x^n)+c (x^(2 n))))^(p+1)))/(b c n (p+1)(x^(2 n (p+1)))))+(e/c)∫(x^(-n))(((b (x^n)+c (x^(2 n))))^(p+1))dx

Program code:

Int[(d_+e_.*x_^n_)*(b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (b*e-d*c)*(b*x^n+c*x^(2*n))^(p+1)/(b*c*n*(p+1)*x^(2*n*(p+1))) + 
  e/c*Int[x^(-n)*(b*x^n+c*x^(2*n))^(p+1),x] /;
FreeQ[{b,c,d,e,n,p},x] && EqQ[n2,2*n] && Not[IntegerQ[p]] && EqQ[n*(2*p+1)+1,0]

2:  ∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ ∧ n(2 p+1)+1≠0 ∧ b e (n p+1)-c d (n(2 p+1)+1)==0

Derivation: Trinomial recurrence 3a with a=0 with b e (n p+1)-c d (n (2 p+1)+1)==0

Rule 1.2.3.3.4.1.2: If  p∉ℤ ∧ n(2 p+1)+1≠0 ∧ b e (n p+1)-c d (n(2 p+1)+1)==0, then

∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((e (x^(-n+1))(((b (x^n)+c (x^(2 n))))^(p+1)))/(c (n(2 p+1)+1)))

Program code:

Int[(d_+e_.*x_^n_)*(b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  e*x^(-n+1)*(b*x^n+c*x^(2*n))^(p+1)/(c*(n*(2*p+1)+1)) /;
FreeQ[{b,c,d,e,n,p},x] && EqQ[n2,2*n] && Not[IntegerQ[p]] && NeQ[n*(2*p+1)+1,0] && EqQ[b*e*(n*p+1)-c*d*(n*(2*p+1)+1),0]

3:  ∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ ∧ n(2 p+1)+1≠0 ∧ b e (n p+1)-c d (n(2 p+1)+1)≠0

Derivation: Trinomial recurrence 3a with a=0

Rule 1.2.3.3.4.1.3: If  p∉ℤ ∧ n(2 p+1)+1≠0 ∧ b e (n p+1)-c d (n(2 p+1)+1)≠0, then

∫(d+e (x^n))(((b (x^n)+c (x^(2 n))))^p)dx  ⟶  
((e (x^(-n+1))(((b (x^n)+c (x^(2 n))))^(p+1)))/(c (n(2 p+1)+1)))-((b e (n p+1)-c d (n(2 p+1)+1))/(c (n(2 p+1)+1)))∫(((b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_)*(b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  e*x^(-n+1)*(b*x^n+c*x^(2*n))^(p+1)/(c*(n*(2*p+1)+1)) - 
  (b*e*(n*p+1)-c*d*(n*(2*p+1)+1))/(c*(n*(2*p+1)+1))*Int[(b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{b,c,d,e,n,p},x] && EqQ[n2,2*n] && Not[IntegerQ[p]] && NeQ[n*(2*p+1)+1,0] && NeQ[b*e*(n*p+1)-c*d*(n*(2*p+1)+1),0]

2:  ∫(((d+e (x^n)))^q)(((b (x^n)+c (x^(2 n))))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^n)+c (x^(2 n))))^p)/((x^(n p))(((b+c (x^n)))^p)))==0

Basis: ((((b (x^n)+c (x^(2 n))))^(FracPart[p]))/((x^(n FracPart[p]))(((b+c (x^n)))^(FracPart[p]))))==((((b (x^n)+c (x^(2 n))))^(FracPart[p]))/((x^(n FracPart[p]))(((b+c (x^n)))^(FracPart[p]))))

Rule 1.2.3.3.4.2: If  p∉ℤ, then

∫(((d+e (x^n)))^q)(((b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((b (x^n)+c (x^(2 n))))^(FracPart[p]))/((x^(n FracPart[p]))(((b+c (x^n)))^(FracPart[p]))))∫(x^(n p))(((d+e (x^n)))^q)(((b+c (x^n)))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (b*x^n+c*x^(2*n))^FracPart[p]/(x^(n*FracPart[p])*(b+c*x^n)^FracPart[p])*Int[x^(n*p)*(d+e*x^n)^q*(b+c*x^n)^p,x] /;
FreeQ[{b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && Not[IntegerQ[p]]

6.  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b z+c (z^2)==(d+e z) ((a/d)+((c z)/e))

Rule 1.2.3.3.6.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((d+e (x^n)))^(p+q)) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(d+e*x^n)^(p+q)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(d+e*x^n)^(p+q)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,n,q},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p]

2:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))

Rule 1.2.3.3.6.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))∫(((d+e (x^n)))^(p+q)) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+c*x^n/e)^FracPart[p])*Int[(d+e*x^n)^(p+q)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]]

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+c*x^n/e)^FracPart[p])*Int[(d+e*x^n)^(p+q)*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

7.  ∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1:  ∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.3.3.7.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈(SuperPlus[ℤ]), then

∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  ⟶  ∫ExpandIntegrand[(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n))),x]dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q*(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[q,0]

Int[(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q*(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && IGtQ[q,0]

2:  ∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q<-1

Derivation: ???

Rule 1.2.3.3.7.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q<-1, then

∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  ⟶  
-(((c (d^2)-b d e+a (e^2)) x (((d+e (x^n)))^(q+1)))/(d (e^2) n (q+1)))+(1/(n(q+1) d (e^2)))∫(((d+e (x^n)))^(q+1)) (c (d^2)-b d e+a (e^2) (n (q+1)+1)+c d e n (q+1) (x^n))dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  -(c*d^2-b*d*e+a*e^2)*x*(d+e*x^n)^(q+1)/(d*e^2*n*(q+1)) + 
  1/(n*(q+1)*d*e^2)*Int[(d+e*x^n)^(q+1)*Simp[c*d^2-b*d*e+a*e^2*(n*(q+1)+1)+c*d*e*n*(q+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && LtQ[q,-1]

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_),x_Symbol] :=
  -(c*d^2+a*e^2)*x*(d+e*x^n)^(q+1)/(d*e^2*n*(q+1)) + 
  1/(n*(q+1)*d*e^2)*Int[(d+e*x^n)^(q+1)*Simp[c*d^2+a*e^2*(n*(q+1)+1)+c*d*e*n*(q+1)*x^n,x],x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && LtQ[q,-1]

3:  ∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

Derivation: Special case of rule for (Subscript[P, q])[x] (((d+e (x^n)))^q)

Rule 1.2.3.3.7.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0, then

∫(((d+e (x^n)))^q) (a+b (x^n)+c (x^(2 n)))dx  ⟶  
((c (x^(n+1)) (((d+e (x^n)))^(q+1)))/(e (n (q+2)+1)))+(1/(e (n (q+2)+1)))∫(((d+e (x^n)))^q) (a e (n (q+2)+1)-(c d (n+1)-b e (n (q+2)+1)) (x^n))dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  c*x^(n+1)*(d+e*x^n)^(q+1)/(e*(n*(q+2)+1)) + 
  1/(e*(n*(q+2)+1))*Int[(d+e*x^n)^q*(a*e*(n*(q+2)+1)-(c*d*(n+1)-b*e*(n*(q+2)+1))*x^n),x] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0]

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_),x_Symbol] :=
  c*x^(n+1)*(d+e*x^n)^(q+1)/(e*(n*(q+2)+1)) + 
  1/(e*(n*(q+2)+1))*Int[(d+e*x^n)^q*(a*e*(n*(q+2)+1)-c*d*(n+1)*x^n),x] /;
FreeQ[{a,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0]

8.  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ

1.  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)+a (e^2)≠0

1.  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)+a (e^2)≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])

1:  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ d e>0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0 and q->(Sqrt[2 d e]), then ((d+e (z^2))/(a+c (z^4)))==((e^2)/(2 c (d+q z+e (z^2))))+((e^2)/(2 c (d-q z+e (z^2))))

Rule 1.2.3.3.8.1.1.1.1.1: If  c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ d e>0, let q->(Sqrt[2 d e]), then

∫((d+e (x^n))/(a+c (x^(2 n))))dx  ⟶  ((e^2)/(2 c))∫(1/(d+q (x^(n/2))+e (x^n)))dx+((e^2)/(2 c))∫(1/(d-q (x^(n/2))+e (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[2*d*e,2]},
  e^2/(2*c)*Int[1/(d+q*x^(n/2)+e*x^n),x] + e^2/(2*c)*Int[1/(d-q*x^(n/2)+e*x^n),x]] /;
FreeQ[{a,c,d,e},x] && EqQ[n2,2*n] && EqQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && PosQ[d*e]

2:  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ d e≯0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0, let q==(Sqrt[-2d e])  then ((d+e (z^2))/(a+c (z^4)))==((d(d-q z))/(2 a(d-q z-e (z^2))))+((d(d+q z))/(2 a(d+q z-e (z^2))))

Rule 1.2.3.3.8.1.1.1.1.2: If  c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ d e≯0, let q->(Sqrt[-2 d e]), then

∫((d+e (x^n))/(a+c (x^(2 n))))dx  ⟶  (d/(2a))∫((d-q (x^(n/2)))/(d-q (x^(n/2))-e (x^n)))dx+(d/(2a))∫((d+q (x^(n/2)))/(d+q (x^(n/2))-e (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[-2*d*e,2]},
  d/(2*a)*Int[(d-q*x^(n/2))/(d-q*x^(n/2)-e*x^n),x] + 
  d/(2*a)*Int[(d+q*x^(n/2))/(d+q*x^(n/2)-e*x^n),x]] /;
FreeQ[{a,c,d,e},x] && EqQ[n2,2*n] && EqQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && NegQ[d*e]

2:  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (n/2)∈(SuperPlus[ℤ])∧ a c>0

Derivation: Algebraic expansion

Basis: If  q->((((a/c)))^(1/4)), then ((d+e (z^2))/(a+c (z^4)))==(((Sqrt[2]) d q-(d-e (q^2)) z)/(2 (Sqrt[2]) c (q^3) ((q^2)-(Sqrt[2]) q z+(z^2))))+(((Sqrt[2]) d q+(d-e (q^2)) z)/(2 (Sqrt[2]) c (q^3) ((q^2)+(Sqrt[2]) q z+(z^2))))

Rule 1.2.3.3.8.1.1.1.2.2: If  c (d^2)+a (e^2)≠0 ∧ c (d^2)-a (e^2)≠0 ∧ (n/2)∈(SuperPlus[ℤ])∧ a c>0, let q->((((a/c)))^(1/4)), then

∫((d+e (x^n))/(a+c (x^(2 n))))dx  ⟶  (1/(2 (Sqrt[2]) c (q^3)))∫(((Sqrt[2]) d q-(d-e (q^2)) (x^(n/2)))/((q^2)-(Sqrt[2]) q (x^(n/2))+(x^n)))dx+(1/(2 (Sqrt[2]) c (q^3)))∫(((Sqrt[2]) d q+(d-e (q^2)) (x^(n/2)))/((q^2)+(Sqrt[2]) q (x^(n/2))+(x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a/c,4]},
  1/(2*Sqrt[2]*c*q^3)*Int[(Sqrt[2]*d*q-(d-e*q^2)*x^(n/2))/(q^2-Sqrt[2]*q*x^(n/2)+x^n),x] + 
  1/(2*Sqrt[2]*c*q^3)*Int[(Sqrt[2]*d*q+(d-e*q^2)*x^(n/2))/(q^2+Sqrt[2]*q*x^(n/2)+x^n),x]] /;
FreeQ[{a,c,d,e},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && NeQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && PosQ[a*c]

3:  ∫((d+e (x^3))/(a+c (x^6)))dx  when c (d^2)+a (e^2)≠0 ∧ (c/a)>0

Derivation: Algebraic expansion

Basis: Let q->((((c/a)))^(1/6)), then ((d+e (x^3))/(a+c (x^6)))==(((q^2) d-e x)/(3 a (q^2) (1+(q^2) (x^2))))+((2 (q^2) d-((Sqrt[3]) (q^3) d-e) x)/(6 a (q^2) (1-(Sqrt[3]) q x+(q^2) (x^2))))+((2 (q^2) d+((Sqrt[3]) (q^3) d+e) x)/(6 a (q^2) (1+(Sqrt[3]) q x+(q^2) (x^2))))

Rule 1.2.3.3.8.1.1.1.3: If  c (d^2)+a (e^2)≠0 ∧ (c/a)>0, let q->((((c/a)))^(1/6)), then

∫((d+e (x^3))/(a+c (x^6)))dx  ⟶  (1/(3 a (q^2)))∫(((q^2) d-e x)/(1+(q^2) (x^2)))dx+(1/(6 a (q^2)))∫((2 (q^2) d-((Sqrt[3]) (q^3) d-e) x)/(1-(Sqrt[3]) q x+(q^2) (x^2)))dx+(1/(6 a (q^2)))∫((2 (q^2) d+((Sqrt[3]) (q^3) d+e) x)/(1+(Sqrt[3]) q x+(q^2) (x^2)))dx

Program code:

Int[(d_+e_.*x_^3)/(a_+c_.*x_^6),x_Symbol] :=
  With[{q=Rt[c/a,6]},
  1/(3*a*q^2)*Int[(q^2*d-e*x)/(1+q^2*x^2),x] + 
  1/(6*a*q^2)*Int[(2*q^2*d-(Sqrt[3]*q^3*d-e)*x)/(1-Sqrt[3]*q*x+q^2*x^2),x] + 
  1/(6*a*q^2)*Int[(2*q^2*d+(Sqrt[3]*q^3*d+e)*x)/(1+Sqrt[3]*q*x+q^2*x^2),x]] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^2+a*e^2,0] && PosQ[c/a]

4:  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)+a (e^2)≠0 ∧ a c≯0 ∧ n∈ℤ

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[-(a/c)]), then ((d+e z)/(a+c (z^2)))==((d+e q)/(2 (a+c q z)))+((d-e q)/(2 (a-c q z)))

Rule 1.2.3.3.8.1.1.1.4: If  c (d^2)+a (e^2)≠0 ∧ a c≯0 ∧ n∈ℤ, let q->(Sqrt[-(a/c)]), then

∫((d+e (x^n))/(a+c (x^(2 n))))dx  ⟶  ((d+e q)/2) ∫ (1/(a+c q (x^n)))dx+((d-e q)/2) ∫ (1/(a-c q (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[-a/c,2]},
  (d+e*q)/2*Int[1/(a+c*q*x^n),x] + (d-e*q)/2*Int[1/(a-c*q*x^n),x]] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && NegQ[a*c] && IntegerQ[n]

5:  ∫((d+e (x^n))/(a+c (x^(2 n))))dx  when c (d^2)+a (e^2)≠0 ∧ (a c>0∨ n∉ℤ)

Derivation: Algebraic expansion

Rule 1.2.3.3.8.1.1.1.5: If  c (d^2)+a (e^2)≠0 ∧ (a c>0∨ n∉ℤ), then

∫((d+e (x^n))/(a+c (x^(2 n))))dx  ⟶  d∫(1/(a+c (x^(2 n))))dx+e∫((x^n)/(a+c (x^(2 n))))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+c_.*x_^n2_),x_Symbol] :=
  d*Int[1/(a+c*x^(2*n)),x] + e*Int[x^n/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && (PosQ[a*c] || Not[IntegerQ[n]])

2.  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0

1.  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])

1:  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ ((2 d)/e)-(b/c)>0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0 and q->(Sqrt[((2 d)/e)-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((e^2)/(2 c (d+e q z+e (z^2))))+((e^2)/(2 c (d-e q z+e (z^2))))

Rule 1.2.3.3.8.1.1.2.1.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ ((2 d)/e)-(b/c)>0, let q->(Sqrt[((2 d)/e)-(b/c)]), then

∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (e/(2 c))∫(1/((d/e)+q (x^(n/2))+(x^n)))dx+(e/(2 c))∫(1/((d/e)-q (x^(n/2))+(x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[2*d/e-b/c,2]},
  e/(2*c)*Int[1/Simp[d/e+q*x^(n/2)+x^n,x],x] + 
  e/(2*c)*Int[1/Simp[d/e-q*x^(n/2)+x^n,x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && (GtQ[2*d/e-b/c,0] || Not[LtQ[2*d/e-b/c,0]] && EqQ[d,e*Rt[a/c,2]])

2:  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c>0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.3.3.8.1.1.2.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q))) ∫ (1/((b/2)-(q/2)+c (x^n)))dx+((e/2)-((2 c d-b e)/(2 q))) ∫ (1/((b/2)+(q/2)+c (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[1/(b/2-q/2+c*x^n),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[1/(b/2+q/2+c*x^n),x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && GtQ[b^2-4*a*c,0]

3:  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  c (d^2)-a (e^2)==0 and q->(Sqrt[-((2 d)/e)-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((e (q-2 z))/(2 c q ((d/e)+q z-(z^2))))+((e (q+2 z))/(2 c q ((d/e)-q z-(z^2))))

Rule 1.2.3.3.8.1.1.2.1.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-a (e^2)==0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c≯0, let q->(Sqrt[-((2 d)/e)-(b/c)]), then

∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (e/(2 c q))∫((q-2 (x^(n/2)))/((d/e)+q (x^(n/2))-(x^n)))dx+(e/(2 c q))∫((q+2 (x^(n/2)))/((d/e)-q (x^(n/2))-(x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[-2*d/e-b/c,2]},
  e/(2*c*q)*Int[(q-2*x^(n/2))/Simp[d/e+q*x^(n/2)-x^n,x],x] + 
  e/(2*c*q)*Int[(q+2*x^(n/2))/Simp[d/e-q*x^(n/2)-x^n,x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-a*e^2,0] && IGtQ[n/2,0] && Not[GtQ[b^2-4*a*c,0]]

2:  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ ((b^2)-4 a c>0 ∨ (n/2)∉(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((d+e z)/(a+b z+c (z^2)))==((e/2)+((2 c d-b e)/(2 q))) (1/((b/2)-(q/2)+c z))+((e/2)-((2 c d-b e)/(2 q))) (1/((b/2)+(q/2)+c z))

Rule 1.2.3.3.8.1.1.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ ((b^2)-4 a c>0 ∨ (n/2)∉(SuperPlus[ℤ])), let q->(Sqrt[(b^2)-4 a c]), then

∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((e/2)+((2 c d-b e)/(2 q))) ∫ (1/((b/2)-(q/2)+c (x^n)))dx+((e/2)-((2 c d-b e)/(2 q))) ∫ (1/((b/2)+(q/2)+c (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  (e/2+(2*c*d-b*e)/(2*q))*Int[1/(b/2-q/2+c*x^n),x] + (e/2-(2*c*d-b*e)/(2*q))*Int[1/(b/2+q/2+c*x^n),x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && (PosQ[b^2-4*a*c] || Not[IGtQ[n/2,0]])

3:  ∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then ((d+e (z^2))/(a+b (z^2)+c (z^4)))==((d r-(d-e q) z)/(2 c q r (q-r z+(z^2))))+((d r+(d-e q) z)/(2 c q r (q+r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.3.3.8.1.1.2.3: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ (n/2)∈(SuperPlus[ℤ])∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((d+e (x^n))/(a+b (x^n)+c (x^(2 n))))dx  ⟶  (1/(2 c q r))∫((d r-(d-e q) (x^(n/2)))/(q-r (x^(n/2))+(x^n)))dx+(1/(2 c q r))∫((d r+(d-e q) (x^(n/2)))/(q+r (x^(n/2))+(x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*q*r)*Int[(d*r-(d-e*q)*x^(n/2))/(q-r*x^(n/2)+x^n),x] + 
  1/(2*c*q*r)*Int[(d*r+(d-e*q)*x^(n/2))/(q+r*x^(n/2)+x^n),x]]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IGtQ[n/2,0] && NegQ[b^2-4*a*c]

2:  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ

Derivation: Algebraic expansion

Rule 1.2.3.3.8.1.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∈ℤ, then

∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ∫ ExpandIntegrand[((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n)))),x]dx

Program code:

Int[(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q/(a+b*x^n+c*x^(2*n)),x],x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[q]

Int[(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_),x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q/(a+c*x^(2*n)),x],x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && IntegerQ[q]

2.  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ

1:  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q<-1

Derivation: Algebraic expansion

Basis: (1/(a+b z+c (z^2)))==((e^2)/(c (d^2)-b d e+a (e^2)))+(((d+e z) (c d-b e-c e z))/((c (d^2)-b d e+a (e^2)) (a+b z+c (z^2))))

Rule 1.2.3.3.8.2.1: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ ∧ q<-1, then

∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((e^2)/(c (d^2)-b d e+a (e^2)))∫(((d+e (x^n)))^q)dx+(1/(c (d^2)-b d e+a (e^2)))∫(((((d+e (x^n)))^(q+1)) (c d-b e-c e (x^n)))/(a+b (x^n)+c (x^(2 n))))dx

Program code:

Int[(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  e^2/(c*d^2-b*d*e+a*e^2)*Int[(d+e*x^n)^q,x] + 
  1/(c*d^2-b*d*e+a*e^2)*Int[(d+e*x^n)^(q+1)*(c*d-b*e-c*e*x^n)/(a+b*x^n+c*x^(2*n)),x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[q]] && LtQ[q,-1]

Int[(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_),x_Symbol] :=
  e^2/(c*d^2+a*e^2)*Int[(d+e*x^n)^q,x] + 
  c/(c*d^2+a*e^2)*Int[(d+e*x^n)^(q+1)*(d-e*x^n)/(a+c*x^(2*n)),x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[q]] && LtQ[q,-1]

2:  ∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  when  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ

Derivation: Algebraic expansion

Basis: If  r=(Sqrt[(b^2)-4a c]), then (1/(a+b z+c (z^2)))==((2c)/(r(b-r+2 c z)))-((2c)/(r(b+r+2 c z)))

Rule 1.2.3.3.8.2.2: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ q∉ℤ, then

∫((((d+e (x^n)))^q)/(a+b (x^n)+c (x^(2 n))))dx  ⟶  ((2 c)/r)∫((((d+e (x^n)))^q)/(b-r+2 c (x^n)))dx-((2 c)/r)∫((((d+e (x^n)))^q)/(b+r+2 c (x^n)))dx

Program code:

Int[(d_+e_.*x_^n_)^q_/(a_+b_.*x_^n_+c_.*x_^n2_),x_Symbol] :=
  With[{r=Rt[b^2-4*a*c,2]},
  2*c/r*Int[(d+e*x^n)^q/(b-r+2*c*x^n),x] - 2*c/r*Int[(d+e*x^n)^q/(b+r+2*c*x^n),x]] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[q]]

Int[(d_+e_.*x_^n_)^q_/(a_+c_.*x_^n2_),x_Symbol] :=
  With[{r=Rt[-a*c,2]},
  -c/(2*r)*Int[(d+e*x^n)^q/(r-c*x^n),x] - c/(2*r)*Int[(d+e*x^n)^q/(r+c*x^n),x]] /;
FreeQ[{a,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[q]]

9.  ∫(d+e (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0

1:  ∫(d+e (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (b^2)-4 a c≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b with m=0

Rule 1.2.3.3.9.1: If  (b^2)-4 a c≠0 ∧ p<-1, then

∫(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  
-((x(d (b^2)-a b e-2 a c d+(b d-2 a e) c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1)))/(a n(p+1) ((b^2)-4 a c)))+(1/(a n(p+1)((b^2)-4 a c) ))·
∫((n p+n+1) d (b^2)-a b e-2a c d(2 n p+2 n+1)+(2 n p+3n+1)(d b-2 a e) c (x^n))(((a+b (x^n)+c (x^(2 n))))^(p+1))dx

Program code:

Int[(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  -x*(d*b^2-a*b*e-2*a*c*d+(b*d-2*a*e)*c*x^n)*(a+b*x^n+c*x^(2*n))^(p+1)/(a*n*(p+1)*(b^2-4*a*c)) + 
  1/(a*n*(p+1)*(b^2-4*a*c))*
    Int[Simp[(n*p+n+1)*d*b^2-a*b*e-2*a*c*d*(2*n*p+2*n+1)+(2*n*p+3*n+1)*(d*b-2*a*e)*c*x^n,x]*
      (a+b*x^n+c*x^(2*n))^(p+1),x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && ILtQ[p,-1]

Int[(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  -x*(d+e*x^n)*(a+c*x^(2*n))^(p+1)/(2*a*n*(p+1)) + 
  1/(2*a*n*(p+1))*Int[(d*(2*n*p+2*n+1)+e*(2*n*p+3*n+1)*x^n)*(a+c*x^(2*n))^(p+1),x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n] && ILtQ[p,-1]

2:  ∫(d+e (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0

Derivation: Algebraic expansion

Rule 1.2.3.3.9.2: If  (b^2)-4 a c≠0, then

∫(d+e (x^n)) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫ExpandIntegrand[(d+e (x^n))(((a+b (x^n)+c (x^(2 n))))^p),x]dx

Program code:

Int[(d_+e_.*x_^n_)*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)*(a+b*x^n+c*x^(2*n))^p,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0]

Int[(d_+e_.*x_^n_)*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)*(a+c*x^(2*n))^p,x],x] /;
FreeQ[{a,c,d,e,n},x] && EqQ[n2,2*n]

10:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx when (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ 2 n p+n q+1≠0

Reference: G&R 2.110.5, CRC 88a

Derivation: Binomial recurrence 3a

Note: This rule reduces the degree of the polynomial in the resulting integrand.

Rule 1.2.3.3.10: If  (b^2)-4 a c≠0 ∧ p∈(SuperPlus[ℤ])∧ 2 n p+n q+1≠0, then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((d+e (x^n)))^q) ((((a+b (x^n)+c (x^(2 n))))^p)-(c^p) (x^(2 n p)))dx+(c^p)∫(x^(2 n p)) (((d+e (x^n)))^q)dx

  ⟶  (((c^p) (x^(2 n p-n+1)) (((d+e (x^n)))^(q+1)))/(e (2 n p+n q+1)))+∫(((d+e (x^n)))^q) ((((a+b (x^n)+c (x^(2 n))))^p)-(c^p) (x^(2 n p))-((d (c^p) (2 n p-n+1)(x^(2 n p-n)))/(e (2 n p+n q+1))))dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  c^p*x^(2*n*p-n+1)*(d+e*x^n)^(q+1)/(e*(2*n*p+n*q+1)) + 
  Int[(d+e*x^n)^q*ExpandToSum[(a+b*x^n+c*x^(2*n))^p-c^p*x^(2*n*p)-d*c^p*(2*n*p-n+1)*x^(2*n*p-n)/(e*(2*n*p+n*q+1)),x],x] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && IGtQ[p,0] && NeQ[2*n*p+n*q+1,0] && IGtQ[n,0] && Not[IGtQ[q,0]]

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  c^p*x^(2*n*p-n+1)*(d+e*x^n)^(q+1)/(e*(2*n*p+n*q+1)) + 
  Int[(d+e*x^n)^q*ExpandToSum[(a+c*x^(2*n))^p-c^p*x^(2*n*p)-d*c^p*(2*n*p-n+1)*x^(2*n*p-n)/(e*(2*n*p+n*q+1)),x],x] /;
FreeQ[{a,c,d,e,n,q},x] && EqQ[n2,2*n] && IGtQ[p,0] && NeQ[2*n*p+n*q+1,0] && IGtQ[n,0] && Not[IGtQ[q,0]]

11:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)≠0 ∧ ((p|q)∈ℤ ∨ p∈(SuperPlus[ℤ])∨ q∈(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Rule 1.2.3.3.11: If  (b^2)-4 a c≠0 ∧ ((p|q)∈ℤ ∨ p∈(SuperPlus[ℤ])∨ q∈(SuperPlus[ℤ])), then

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫ExpandIntegrand[(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p),x]dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x],x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && NeQ[c*d^2-b*d*e+a*e^2,0] && 
  (IntegersQ[p,q] && Not[IntegerQ[n]] || IGtQ[p,0] || IGtQ[q,0] && Not[IntegerQ[n]])

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(d+e*x^n)^q*(a+c*x^(2*n))^p,x],x] /;
FreeQ[{a,c,d,e,n,p,q},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && 
  (IntegersQ[p,q] && Not[IntegerQ[n]] || IGtQ[p,0] || IGtQ[q,0] && Not[IntegerQ[n]])

12:  ∫(((d+e (x^n)))^q) (((a+c (x^(2 n))))^p)dx  when c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ q∈(SuperMinus[ℤ])

Derivation: Algebraic expansion

Basis: If  q∈ℤ, then (((d+e (x^n)))^q)==((((d/((d^2)-(e^2) (x^(2 n))))-((e (x^n))/((d^2)-(e^2) (x^(2 n))))))^(-q))

Note: Resulting integrands are of the form (x^m) (((a+b (x^(2 n))))^p) (((c+d (x^(2 n))))^q) which are integrable in terms of the Appell hypergeometric function .

Rule 1.2.3.3.12: If  c (d^2)+a (e^2)≠0 ∧ p∉ℤ ∧ q∈(SuperMinus[ℤ]), then

∫(((d+e (x^n)))^q) (((a+c (x^(2 n))))^p)dx  ⟶  ∫(((a+c (x^(2 n))))^p) ExpandIntegrand[((((d/((d^2)-(e^2) (x^(2 n))))-((e (x^n))/((d^2)-(e^2) (x^(2 n))))))^(-q)),x]dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  Int[ExpandIntegrand[(a+c*x^(2*n))^p,(d/(d^2-e^2*x^(2*n))-e*x^n/(d^2-e^2*x^(2*n)))^(-q),x],x] /;
FreeQ[{a,c,d,e,n,p},x] && EqQ[n2,2*n] && NeQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]] && ILtQ[q,0]

U:  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Rule 1.2.3.3.X:

∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  Unintegrable[(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n]

Int[(d_+e_.*x_^n_)^q_*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  Unintegrable[(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,n,p,q},x] && EqQ[n2,2*n]

S:  ∫(((d+e (u^n)))^q)(((a+b (u^n)+c (u^(2 n))))^p)dx  when  u==f+g x

Derivation: Integration by substitution

Rule 1.2.3.3.S: If  u==f+g x, then

∫(((d+e (u^n)))^q)(((a+b (u^n)+c (u^(2 n))))^p)dx  ⟶  (1/g)Subst[∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx,x,u]

Program code:

Int[(d_+e_.*u_^n_)^q_.*(a_+b_.*u_^n_+c_.*u_^n2_)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x],x,u] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && LinearQ[u,x] && NeQ[u,x]

Int[(d_+e_.*u_^n_)^q_.*(a_+c_.*u_^n2_)^p_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(d+e*x^n)^q*(a+c*x^(2*n))^p,x],x,u] /;
FreeQ[{a,c,d,e,n,p,q},x] && EqQ[n2,2*n] && LinearQ[u,x] && NeQ[u,x]

Rules for integrands of the form(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)

1.  ∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∈ℤ ∨ q∈ℤ

1:  ∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  q∈ℤ ∧ (n>0 ∨ p∉ℤ)

Derivation: Algebraic simplification

Basis: If  q∈ℤ, then  (((d+e (x^(-n))))^q)==(x^(-n q)) (((e+d (x^n)))^q)

Rule: If  q∈ℤ ∧ (n>0 ∨ p∉ℤ), then

∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(x^(-n q)) (((e+d (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^mn_.)^q_.*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(-n*q)*(e+d*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p},x] && EqQ[n2,2*n] && EqQ[mn,-n] && IntegerQ[q] && (PosQ[n] || Not[IntegerQ[p]])

Int[(d_+e_.*x_^mn_.)^q_.*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  Int[x^(mn*q)*(e+d*x^(-mn))^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,mn,p},x] && EqQ[n2,-2*mn] && IntegerQ[q] && (PosQ[n2] || Not[IntegerQ[p]])

2:  ∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  when  p∈ℤ

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then  (((a+b (x^(-n))+c (x^(-2 n))))^p)==(x^(-2 n p)) (((c+b (x^n)+a (x^(2 n))))^p)

Rule: If  p∈ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  ⟶  ∫(x^(-2 n p)) (((d+e (x^n)))^q) (((c+b (x^n)+a (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_.)^q_.*(a_.+b_.*x_^mn_.+c_.*x_^mn2_.)^p_.,x_Symbol] :=
  Int[x^(-2*n*p)*(d+e*x^n)^q*(c+b*x^n+a*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[mn,-n] && EqQ[mn2,2*mn] && IntegerQ[p]

Int[(d_+e_.*x_^n_.)^q_.*(a_.+c_.*x_^mn2_.)^p_.,x_Symbol] :=
  Int[x^(-2*n*p)*(d+e*x^n)^q*(c+a*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,n,q},x] && EqQ[mn2,-2*n] && IntegerQ[p]

2.  ∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ

1:  ∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((d+e (x^(-n))))^q))/(((1+((d (x^n))/e)))^q))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((e^(IntPart[q])) (x^(n FracPart[q])) (((d+e (x^(-n))))^(FracPart[q])))/(((1+((d (x^n))/e)))^(FracPart[q]))) ∫(x^(-n q)) (((1+((d (x^n))/e)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^mn_.)^q_*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  e^IntPart[q]*x^(n*FracPart[q])*(d+e*x^(-n))^FracPart[q]/(1+d*x^n/e)^FracPart[q]*Int[x^(-n*q)*(1+d*x^n/e)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[mn,-n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

Int[(d_+e_.*x_^mn_.)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  e^IntPart[q]*x^(-mn*FracPart[q])*(d+e*x^mn)^FracPart[q]/(1+d*x^(-mn)/e)^FracPart[q]*Int[x^(mn*q)*(1+d*x^(-mn)/e)^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,mn,p,q},x] && EqQ[n2,-2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n2]

x:  ∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((d+e (x^(-n))))^q))/(((e+d (x^n)))^q))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(((d+e (x^(-n))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  (((x^(n FracPart[q])) (((d+e (x^(-n))))^(FracPart[q])))/(((e+d (x^n)))^(FracPart[q]))) ∫(x^(-n q)) (((e+d (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

(* Int[(d_+e_.*x_^mn_.)^q_*(a_.+b_.*x_^n_.+c_.*x_^n2_.)^p_.,x_Symbol] :=
  x^(n*FracPart[q])*(d+e*x^(-n))^FracPart[q]/(e+d*x^n)^FracPart[q]*Int[x^(-n*q)*(e+d*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[n2,2*n] && EqQ[mn,-n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n] *)

(* Int[(d_+e_.*x_^mn_.)^q_*(a_+c_.*x_^n2_.)^p_.,x_Symbol] :=
  x^(-mn*FracPart[q])*(d+e*x^mn)^FracPart[q]/(e+d*x^(-mn))^FracPart[q]*Int[x^(mn*q)*(e+d*x^(-mn))^q*(a+c*x^n2)^p,x] /;
FreeQ[{a,c,d,e,mn,p,q},x] && EqQ[n2,-2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n2] *)

2:  ∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  when  p∉ℤ ∧ q∉ℤ ∧ n>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(2 n p)) (((a+b (x^(-n))+c (x^(-2 n))))^p))/(((c+b (x^n)+a (x^(2 n))))^p))==0

Rule: If  p∉ℤ ∧ q∉ℤ ∧ n>0, then

∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^(-2 n))))^p)dx  ⟶  (((x^(2 n FracPart[p])) (((a+b (x^(-n))+c (x^(-2 n))))^(FracPart[p])))/(((c+b (x^n)+a (x^(2 n))))^(FracPart[p]))) ∫(x^(-2 n p)) (((d+e (x^n)))^q) (((c+b (x^n)+a (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_.)^q_.*(a_.+b_.*x_^mn_.+c_.*x_^mn2_.)^p_,x_Symbol] :=
  x^(2*n*FracPart[p])*(a+b*x^(-n)+c*x^(-2*n))^FracPart[p]/(c+b*x^n+a*x^(2*n))^FracPart[p]*
    Int[x^(-2*n*p)*(d+e*x^n)^q*(c+b*x^n+a*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[mn,-n] && EqQ[mn2,2*mn] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

Int[(d_+e_.*x_^n_.)^q_.*(a_.+c_.*x_^mn2_.)^p_,x_Symbol] :=
  x^(2*n*FracPart[p])*(a+c*x^(-2*n))^FracPart[p]/(c+a*x^(2*n))^FracPart[p]*
    Int[x^(-2*n*p)*(d+e*x^n)^q*(c+a*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,n,p,q},x] && EqQ[mn2,-2*n] && Not[IntegerQ[p]] && Not[IntegerQ[q]] && PosQ[n]

Rules for integrands of the form(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)

1:  ∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∈ℤ

Derivation: Algebraic normalization

Basis: a+b (x^(-n))+c (x^n)==(x^(-n)) (b+a (x^n)+c (x^(2 n)))

Rule: If  p∈ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  ∫(x^(-n p)) (((d+e (x^n)))^q) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  Int[x^(-n*p)*(d+e*x^n)^q*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,q},x] && EqQ[mn,-n] && IntegerQ[p]

2:  ∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  when  p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==0

Basis: (((x^(n p)) (((a+b (x^(-n))+c (x^n)))^p))/(((b+a (x^n)+c (x^(2 n))))^p))==(((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))

Rule: If  p∉ℤ, then

∫(((d+e (x^n)))^q) (((a+b (x^(-n))+c (x^n)))^p)dx  ⟶  (((x^(n FracPart[p])) (((a+b (x^(-n))+c (x^n)))^(FracPart[p])))/(((b+a (x^n)+c (x^(2 n))))^(FracPart[p])))∫(x^(-n p)) (((d+e (x^n)))^q) (((b+a (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^mn_+c_.*x_^n_.)^p_.,x_Symbol] :=
  x^(n*FracPart[p])*(a+b/x^n+c*x^n)^FracPart[p]/(b+a*x^n+c*x^(2*n))^FracPart[p]*
    Int[x^(-n*p)*(d+e*x^n)^q*(b+a*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && EqQ[mn,-n] && Not[IntegerQ[p]]

Rules for integrands of the form(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)

1:  ∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/(((b+2 c (x^n)))^(2 p)))==0

Basis: If  (b^2)-4 a c==0, then ((((a+b (x^n)+c (x^(2 n))))^p)/(((b+2 c (x^n)))^(2 p)))==((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((4c))^(IntPart[p]))(((b+2 c (x^n)))^(2 FracPart[p]))))

Rule: If  (b^2)-4 a c==0 ∧ 2p∉ℤ, then

∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((4c))^(IntPart[p]))(((b+2 c (x^n)))^(2 FracPart[p]))))∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((b+2 c (x^n)))^(2 p))dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(f_+g_.*x_^n_)^r_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/((4*c)^IntPart[p]*(b+2*c*x^n)^(2*FracPart[p]))*
    Int[(d+e*x^n)^q*(f+g*x^n)^r*(b+2*c*x^n)^(2*p),x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r},x] && EqQ[n2,2*n] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]]

2.  ∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0

1:  ∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  c (d^2)-b d e+a (e^2)==0, then a+b z+c (z^2)==(d+e z) ((a/d)+((c z)/e))

Rule: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∈ℤ, then

∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫(((d+e (x^n)))^(p+q)) (((f+g (x^n)))^r) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(f_+g_.*x_^n_)^r_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(d+e*x^n)^(p+q)*(f+g*x^n)^r*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,q,r},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && IntegerQ[p]

Int[(d_+e_.*x_^n_)^q_.*(f_+g_.*x_^n_)^r_.*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(d+e*x^n)^(p+q)*(f+g*x^n)^r*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,f,g,n,q,r},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && IntegerQ[p]

2:  ∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  when (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  c (d^2)-b d e+a (e^2)==0, then (∂_x)((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==0

Basis: If  c (d^2)-b d e+a (e^2)==0, then ((((a+b (x^n)+c (x^(2 n))))^p)/((((d+e (x^n)))^p) ((((a/d)+((c (x^n))/e)))^p)))==((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))

Rule: If  (b^2)-4 a c≠0 ∧ c (d^2)-b d e+a (e^2)==0 ∧ p∉ℤ, then

∫(((d+e (x^n)))^q) (((f+g (x^n)))^r) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((a+b (x^n)+c (x^(2 n))))^(FracPart[p]))/((((d+e (x^n)))^(FracPart[p])) ((((a/d)+((c (x^n))/e)))^(FracPart[p]))))∫(((d+e (x^n)))^(p+q)) (((f+g (x^n)))^r) ((((a/d)+((c (x^n))/e)))^p)dx

Program code:

Int[(d_+e_.*x_^n_)^q_.*(f_+g_.*x_^n_)^r_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+b*x^n+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+(c*x^n)/e)^FracPart[p])*
    Int[(d+e*x^n)^(p+q)*(f+g*x^n)^r*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r},x] && EqQ[n2,2*n] && NeQ[b^2-4*a*c,0] && EqQ[c*d^2-b*d*e+a*e^2,0] && Not[IntegerQ[p]]

Int[(d_+e_.*x_^n_)^q_.*(f_+g_.*x_^n_)^r_.*(a_+c_.*x_^n2_)^p_,x_Symbol] :=
  (a+c*x^(2*n))^FracPart[p]/((d+e*x^n)^FracPart[p]*(a/d+(c*x^n)/e)^FracPart[p])*
    Int[(d+e*x^n)^(p+q)*(f+g*x^n)^r*(a/d+c/e*x^n)^p,x] /;
FreeQ[{a,c,d,e,f,g,n,p,q,r},x] && EqQ[n2,2*n] && EqQ[c*d^2+a*e^2,0] && Not[IntegerQ[p]]

3.  ∫((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0

1:  ∫((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0)

Derivation: Algebraic simplification

Basis: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0), then ((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q)==((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q)

Rule: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0 ∧ (q∈ℤ ∨ (Subscript[d, 1])>0 ∧ (Subscript[d, 2])>0), then

∫((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ∫((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d1_+e1_.*x_^non2_.)^q_.*(d2_+e2_.*x_^non2_.)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  Int[(d1*d2+e1*e2*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n,p,q},x] && EqQ[n2,2*n] && EqQ[non2,n/2] && EqQ[d2*e1+d1*e2,0] && (IntegerQ[q] || GtQ[d1,0] && GtQ[d2,0])

2:  ∫((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0

Derivation: Piecewise constant extraction

Basis: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0, then (∂_x)((((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q))/((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q))==0

Rule: If  (Subscript[d, 2]) (Subscript[e, 1])+(Subscript[d, 1]) (Subscript[e, 2])==0, then

∫((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^q) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  ((((((Subscript[d, 1])+(Subscript[e, 1]) (x^(n/2))))^(FracPart[q])) ((((Subscript[d, 2])+(Subscript[e, 2]) (x^(n/2))))^(FracPart[q])))/((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^(FracPart[q])))∫((((Subscript[d, 1]) (Subscript[d, 2])+(Subscript[e, 1]) (Subscript[e, 2]) (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(d1_+e1_.*x_^non2_.)^q_.*(d2_+e2_.*x_^non2_.)^q_.*(a_.+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  (d1+e1*x^(n/2))^FracPart[q]*(d2+e2*x^(n/2))^FracPart[q]/(d1*d2+e1*e2*x^n)^FracPart[q]*
    Int[(d1*d2+e1*e2*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n,p,q},x] && EqQ[n2,2*n] && EqQ[non2,n/2] && EqQ[d2*e1+d1*e2,0]

Rules for integrands of the form(A+B (x^m)) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)

1:  ∫(A+B (x^m)) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  when  m-n+1==0

Derivation: Algebraic expansion

Rule: If  m-n+1==0, then

∫(A+B (x^m)) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx  ⟶  A ∫(((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx+B ∫(x^m) (((d+e (x^n)))^q) (((a+b (x^n)+c (x^(2 n))))^p)dx

Program code:

Int[(A_+B_.*x_^m_.)*(d_+e_.*x_^n_)^q_.*(a_+b_.*x_^n_+c_.*x_^n2_)^p_.,x_Symbol] :=
  A*Int[(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] + B*Int[x^m*(d+e*x^n)^q*(a+b*x^n+c*x^(2*n))^p,x] /;
FreeQ[{a,b,c,d,e,A,B,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[m-n+1,0]

Int[(A_+B_.*x_^m_.)*(d_+e_.*x_^n_)^q_.*(a_+c_.*x_^n2_)^p_.,x_Symbol] :=
  A*Int[(d+e*x^n)^q*(a+c*x^(2*n))^p,x] + B*Int[x^m*(d+e*x^n)^q*(a+c*x^(2*n))^p,x] /;
FreeQ[{a,c,d,e,A,B,m,n,p,q},x] && EqQ[n2,2*n] && EqQ[m-n+1,0]